stop using submodule

packages/chr/Benchmarks/fibonacci.chr

@@ -0,0 +1,42 @@
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%
+%% 16 June 2003 Bart Demoen, Tom Schrijvers, K.U.Leuven
+%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+:- module(fibonacci,[main/0,main/1]).
+
+:- use_module(library(chr)).
+
+:- chr_constraint fibonacci/2.
+
+%% fibonacci(N,M) is true iff  M is the Nth Fibonacci number.
+
+%% Top-down Evaluation with effective Tabulation
+%% Contrary to the version in the SICStus manual, this one does "true"
+%% tabulation
+
+fibonacci(N,M1) # ID \ fibonacci(N,M2) <=> var(M2) | M1 = M2 pragma passive(ID).
+
+fibonacci(0,M) ==> M = 1.
+
+fibonacci(1,M) ==> M = 1.
+
+fibonacci(N,M) ==>
+	N > 1 |
+		N1 is N-1,
+		fibonacci(N1,M1),
+		N2 is N-2,
+		fibonacci(N2,M2),
+		M is M1 + M2.
+
+main :-
+	main(2000).
+
+main(N):-
+	cputime(X),
+	fibonacci(N,_),
+	cputime( Now),
+	Time is Now-X,
+	write(bench(fibonacci ,N,Time, 0, hprolog)),write('.'), nl.
+