Predicate declarations and definitions can be encapsulated inside objects and categories. Protocols can only contain predicate declarations.
All object (or category) predicates that we want to access from other objects must be explicitly declared. A predicate declaration must contain, at least, a scope directive. Other directives may be used to document the predicate or to ensure proper compilation of the predicate definitions.
A predicate can be public, protected or private. Public predicates can be called from any object. Protected predicates can only be called from the container object or from a container descendant. Private predicates can only be called from the container object.
The scope declarations are made using the public/1, protected/1 and private/1 directives. For example:
:- public(init/1).
:- protected(valid_init_option/1).
:- private(process_init_options/1).
Note that we do not need to write scope declarations for all defined predicates. If a predicate does not have a scope declaration, it is assumed that the predicate is private, although it will be invisible to the reflection methods and to the message and error handling mechanisms.
Many predicates cannot be called with arbitrary arguments with arbitrary instantiation status. The valid arguments and instantiation modes can be documented by using the mode/2 directive. For instance:
:- mode(member(?term, +list), zero_or_more).
The first argument describes a valid calling mode. The minimum information will be the instantiation mode of each argument. There are four possible values (described in [ISO 95]):
+- Argument must be instantiated.
-- Argument must be a free (non-instantiated) variable.
?- Argument can either be instantiated or free.
@- Argument will not be modified.
These four mode atoms are also declared as prefix operators by the Logtalk preprocessor. This makes it possible to include type information for each argument like in the example above. Some of the possible type values are: event, object, category, protocol, callable, term, nonvar, var, atomic, atom, number, integer, float, compound, and list. The first four are Logtalk specific. The remaining are common Prolog types. We can also use our own types that can be either atoms or compound terms.
The second argument documents the number of proofs (or solutions) for the specified mode. The possible values are:
zero- Predicate always fails.
one- Predicate always succeeds once.
zero_or_one- Predicate either fails or succeeds.
zero_or_more- Predicate has zero or more solutions.
one_or_more- Predicate has one or more solutions.
error- Predicate will throw an error (see below).
Mode declarations can also be used to document that some call modes will throw an error. For instance, regarding the arg/3 ISO Prolog built-in predicate, we may write:
:- mode(arg(-, -, +), error).
Note that most predicates have more than one valid mode implying several mode directives. For example, to document the possible use modes of the atom_concat/3 ISO built-in predicate we would write:
:- mode(atom_concat(?atom, ?atom, +atom), one_or_more).
:- mode(atom_concat(+atom, +atom, -atom), zero_or_one).
Some old Prolog compilers supported some sort of mode directives to improve performance. To the best of my knowledge, there is no modern Prolog compiler supporting these kind of directive. The current version of the Logtalk preprocessor just parses and than discards this directive. Nevertheless, the use of mode directives is a good starting point to the documentation of your predicates.
Some predicates may have arguments that will be called as goals. To ensure that these calls will be executed in the correct scope we need to use the metapredicate/1 directive. For example:
:- metapredicate(findall(*, ::, *)).
The predicate arguments in this directive have the following meaning:
::- Meta-argument that will be called as a goal.
*- Normal argument.
This is similar to the declaration of metapredicates in the ISO draft for Prolog modules except that we use the atom :: instead of : to be consistent with the message sending operators.
Since each Logtalk entity is independently compiled, this directive must be included in every object or category that contains a definition for the described predicate, even if the predicate declaration is inherited from another entity, to ensure proper compilation of meta-arguments.
The clause of an object (or category) predicate may not be contiguous. In that case, we must declare the predicate discontiguous by using the discontiguous/1 directive:
:- discontiguous(foo/1).
This is a directive that we should avoid using: it makes your code harder to read and it is not supported by some Prolog compilers.
Because each Logtalk entity is compiled independently from other entities, this directive must be included in every object or category that contains a definition for the described predicate (even if the predicate declaration is inherited from other entity).
An object (or category) predicate can be static or dynamic. By default, all object predicates are static. To declare a dynamic predicate we use the dynamic/1 directive:
:- dynamic(foo/1).
Because each Logtalk entity is compiled independently from other entities, this directive must be included in every object or category that contains a definition for the described predicate (even if the predicate declaration is inherited from other entity). If we omit the dynamic declaration then the predicate definition will be compiled to static code. Note that any static object may declare and define dynamic predicates.
An object (or category) predicate can be declared as an operator using the familiar op/3 directive:
:- op(Priority, Specifier, Operator).
Operators are local to the object (or category) where they are declared. This means that, if you declare a public predicate as an operator, you cannot use operator notation when sending to an object (where the predicate is visible) the respective message (as this would imply visibility of the operator declaration in the context of the sender of the message).
When a predicate makes heavy use of predicates defined on other objects, its definition can be excessively verbose due to all the necessary message sending constructs. Consider the following example:
foo :-
...,
findall(X, list::member(X, L), A),
list::append(A, B, C),
list::select(Y, C, R),
...
Logtalk provides a directive, uses/2, which allows us to simplify the code above. The usage template for this directive is:
:- uses(Object, [Functor1/Arity1, Functor2/Arity2, ...]).
Rewriting the code above using this directive results in a simplified and more easily readable predicate definition:
:- uses(list,
[append/3, member/2, select/3]).
foo :-
...,
findall(X, member(X, L), A),
append(A, B, C),
select(Y, C, R),
...
The uses/2 directive allows simpler predicate definitions as long as there are no conflicts between the predicates declared in the directive and the predicates defined in the object (or category) containing the directive. A predicate cannot be listed in more than one uses/2 directive. In addition, a uses/2 directive cannot list a predicate which is defined in the object (or category) containing the directive. Any conflicts are reported by the Logtalk pre-processor as compilation errors.
In the current Logtalk version, the omission of the Object:: prefix is not supported when the predicate call occurs as an argument of a user-defined meta-predicate (Logtalk specified meta-predicates and Prolog non-standard meta-predicates declared in the config files pose no problem).
A predicate can be documented with arbitrary user-defined information by using the info/2 directive:
:- info(Functor/Arity, List).
The second argument is a list of Key is Value terms. See the Documenting Logtalk programs session for details.
We define object predicates as we have always defined Prolog predicates, the only difference be that we have four more control structures (the three message sending operators plus the external call operator) to play with. For example, if we wish to define an object containing common utility list predicates like append/2 or member/2 we could write something like:
:- object(list).
:- public(append/3).
:- public(member/2).
append([], L, L).
append([H| T], L, [H| T2]) :-
append(T, L, T2).
member(H, [H| _]).
member(H, [_| T]) :-
member(H, T).
:- end_object.
Note that, abstracting from the opening and closing object directives and the scope directives, what we have written is plain Prolog. Calls in a predicate definition body default to the local predicates, unless we use the message sending operators or the external call operator. This enables easy conversion from Prolog code to Logtalk objects: we just need to add the necessary encapsulation and scope directives to the old code.
Because a category can be imported by several different objects, dynamic private predicates must be called using the ::/1 message sending operator. This ensures that the correct predicate definition will be used. For example, if we want to define a category implementing variables using destructive assignment we could write:
:- category(variable).
:- public(get/2).
:- public(set/2).
:- private(value_/2).
:- dynamic(value_/2).
get(Var, Value) :-
::value_(Var, Value).
set(Var, Value) :-
::retractall(value_(Var, _)),
::asserta(value_(Var, Value).
:- end_category.
This way, each importing object will have its own definition for the value_/2 private predicate. Furthermore, the get/2 and set/2 predicates will always access/update the correct definition, contained in the object receiving the messages.
A category may only contain clauses for static predicates. Nevertheless, as the example above illustrates, there are no retrictions in declaring and calling dynamic predicates from inside a category.
Logtalk defines a set of built-in object predicates or methods to access message execution context, to find sets of solutions, to inspect objects and for database handling. Similar to Prolog built-in predicates, these built-in methods should not be redefined.
Logtalk defines four built-in methods to access an object execution context. These methods are compiled in-line and can be freely used without worrying about performance penalties. When called from inside a category, these methods refer to the execution context of the object importing the category.
To find the object that received the message under execution we may use the self/1 method. We may also retrieve the object that has sent the message under execution using the sender/1 method.
The method this/1 enables us to retrieve the name of the object that contains the code that is being executed instead of using the name directly. This helps to avoid breaking the code if we decide to change the object name and forget to change the name references.
Here is a short example including calls to these three object execution context methods:
:- object(test).
:- public(test/0).
test :-
this(This),
write('Executing a predicate definition contained in '), writeq(This), nl,
self(Self),
write('to answer a message received by '), writeq(Self), nl,
sender(Sender),
write('that was sent by '), writeq(Sender), nl, nl.
:- end_object.
:- object(descendant,
extends(test)).
:- end_object.
After compiling and loading these two objects, we can try the following goal:
| ?- descendant::test.
Executing a predicate definition contained in test
to answer a message received by descendant
that was sent by user
yes
For parametric objects, the method parameter/2 enables us to retrieve current parameter values (see the session on parametric objects for a detailed description). For example:
:- object(block(_Color)).
:- public(test/0).
test :-
parameter(1, Color),
write('Color parameter value is '), writeq(Color), nl.
:- end_object.
After compiling and loading these two objects, we can try the following goal:
| ?- block(blue)::test.
Color parameter value is blue
yes
The method parameter/2 is only compiled in-ilne when used inside objects; its use inside categories implies a call to the built-in Prolog predicate arg/3. Nevertheless, note that calls to parameter/2 from inside categories are inherently problematic: a category may be implemented by several objects, both parametric (with different number of parameters) and non-parametric. Care must be taken to ensure that a parametric object importing such a category match the interpretation of its parameters used in the category.
Logtalk provides a set of built-in methods for object database handling similar to the usual database Prolog predicates: abolish/1, asserta/1, assertz/1, clause/2, retract/1 and retractall/1. These methods always operate on the database of the object receiving the corresponding message.
The usual all solutions meta-predicates are pre-defined methods in Logtalk: bagof/3, findall/3 and setof/3. There is also a forall/2 method that implements generate and test loops.
Logtalk provides two built-in methods for inspecting object predicates: predicate_property/2, that return predicate properties and current_predicate/1, that enables us to query about predicate definitions. See below for a more detailed description of both methods.
We can find the properties of visible predicates by calling the predicate_property/2 built-in method. For example:
| ?- bar::predicate_property(foo(_), Property).
Note that this method respects the predicate's scope declarations. For instance, the above call will only return properties for public predicates.
An object's set of visible predicates is the union of all the predicates declared for the object with all the built-in methods and all the Logtalk and Prolog built-in predicates.
Possible predicate propertie values are:
public, protected, privatestatic, dynamicbuilt_inmetapredicate(Mode)declared_in(Entity)defined_in(Entity)
The last two properties, declared_in/1 and defined_in/1, do not apply to built-in methods and Logtalk or Prolog built-in predicates.
Note that if a predicate is declared in a category imported by the object, it will be the category name - not the object name - which will be returned by the property declared_in/1.
We can find, by backtracking, all visible user predicates by calling the current_predicate/1 built-in method. This method respects the predicate's scope declarations. For instance, the following call:
| ?- some_object::current_predicate(Functor/Arity).
will only return user predicates that are declared public.